zippypretext and other modules

.github/skip_nf_test.json

@@ -2,11 +2,14 @@
     "conda": [
         "modules/sanger-tol/ancestral",
         "modules/sanger-tol/longranger",
+        "modules/sanger-tol/pretext/pretext2asm",
+        "modules/sanger-tol/pretext/juicerc",
         "modules/sanger-tol/telomere",
         "subworkflows/sanger-tol/ancestral",
         "subworkflows/sanger-tol/fasta_purge_retained_haplotype",
+        "subworkflows/sanger-tol/fasta_10x_polishing_longranger_freebayes",
         "subworkflows/sanger-tol/telo_finder",
-        "subworkflows/sanger-tol/fasta_10x_polishing_longranger_freebayes"
+        "subworkflows/sanger-tol/zippypretext"
     ],
     "docker": ["modules/sanger-tol/longranger", "subworkflows/sanger-tol/fasta_10x_polishing_longranger_freebayes"],
     "singularity": []

modules/sanger-tol/pretext/juicerc/main.nf

@@ -0,0 +1,45 @@
+process PRETEXT_JUICERC {
+    tag "${meta.id}"
+    label 'process_medium'
+
+    container 'quay.io/sanger-tol/juicerc:1.2-c1'
+
+    input:
+    tuple val(meta), path(hicmap)
+    path agpfile
+    path idxfile
+
+    output:
+    tuple val(meta), path("*_alignment_sorted.txt"), emit: alignment
+    path("juicercout.log"), emit: outlog
+    tuple val("${task.process}"), val('juicer_pre'), eval('juicer pre --version'), topic: versions, emit: versions_juicer_pre
+    // juicerc container has no CLI --version; pin to container tag (bump when `container` changes)
+    tuple val("${task.process}"), val('juicerc'), val('1.2'), topic: versions, emit: versions_juicerc
+
+    when:
+    task.ext.when == null || task.ext.when
+
+    script:
+    if (workflow.profile.tokenize(',').intersect(['conda', 'mamba']).size() >= 1) {
+        error "PRETEXT_JUICERC module does not support Conda. Please use Docker / Singularity instead."
+    }
+    def prefix   = task.ext.prefix   ?: "${meta.id}"
+    def sort_mem = (task.memory.toGiga() * 0.9).intValue()
+
+    """
+    juicer pre -q 0 ${hicmap} ${agpfile} ${idxfile} 2>juicercout.log \\
+        | LC_ALL=C sort -k2,2d -k6,6d -T . --parallel=${task.cpus} -S${sort_mem}G \\
+        | awk '\$3>=0 && \$7>=0' \\
+        > ${prefix}_alignment_sorted.txt
+    """
+
+    stub:
+    if (workflow.profile.tokenize(',').intersect(['conda', 'mamba']).size() >= 1) {
+        error "PRETEXT_JUICERC module does not support Conda. Please use Docker / Singularity instead."
+    }
+    def prefix  = task.ext.prefix   ?: "${meta.id}"
+    """
+    touch ${prefix}_alignment_sorted.txt
+    touch juicercout.log
+    """
+}

modules/sanger-tol/pretext/juicerc/meta.yml

@@ -0,0 +1,107 @@
+name: "pretext_juicerc"
+description: |
+  Remap Hi-C alignments onto a curated AGP with `juicer pre`, sort pairs, and filter
+  invalid coordinates — equivalent to the zippypretext `juicerc.sh` wrapper.
+keywords:
+  - pretext
+  - juicer
+  - hic
+  - agp
+  - curation
+tools:
+  - juicer_pre:
+      description: |
+        Remap Hi-C contacts from a `.bin` or BAM onto scaffold coordinates in an AGP
+        using a contig-level FASTA index (`juicer pre -q 0`).
+      homepage: https://github.com/aidenlab/juicer/wiki/Juicer-Tools-Quick-Start
+      documentation: https://github.com/aidenlab/juicer/wiki/Juicer-Tools-Quick-Start
+      licence:
+        - "MIT"
+      identifier: ""
+input:
+  - - meta:
+        type: map
+        description: |
+          Groovy Map containing sample information
+          e.g. `[ id:'sample1' ]`
+    - hicmap:
+        type: file
+        description: Hi-C alignment file (BAM or Juicer `.bin` contacts)
+        pattern: "*.{bam,bin}"
+        ontologies:
+          - edam: "http://edamontology.org/format_2572" # BAM
+          - edam: "http://edamontology.org/format_2333" # BIN
+  - agpfile:
+      type: file
+      description: AGP file describing scaffold coordinates (typically output of
+        `pretext2asm`)
+      pattern: "*.agp"
+      ontologies:
+        - edam: "http://edamontology.org/format_3693" # AGP
+  - idxfile:
+      type: file
+      description: FASTA index (`.fai`) matching the contig-level Hi-C assembly
+      pattern: "*.fai"
+      ontologies: []
+output:
+  alignment:
+    - - meta:
+          type: map
+          description: Groovy Map containing sample information
+      - "*_alignment_sorted.txt":
+          type: file
+          description: Sorted Hi-C alignment records remapped to scaffold
+            coordinates
+          pattern: "*_alignment_sorted.txt"
+          ontologies:
+            - edam: http://edamontology.org/format_2330 # Textual format
+  outlog:
+    - juicercout.log:
+        type: file
+        description: Log file written by `juicerc.sh`
+        pattern: "juicercout.log"
+        ontologies: []
+  versions_juicer_pre:
+    - - ${task.process}:
+          type: string
+          description: The process the versions were collected from
+      - juicer_pre:
+          type: string
+          description: The tool name
+      - juicer pre --version:
+          type: eval
+          description: The expression to obtain the version of the tool
+  versions_juicerc:
+    - - ${task.process}:
+          type: string
+          description: The process the versions were collected from
+      - juicerc:
+          type: string
+          description: The tool name
+      - "1.2":
+          type: string
+          description: The version of the tool
+topics:
+  versions:
+    - - ${task.process}:
+          type: string
+          description: The process the versions were collected from
+      - juicer_pre:
+          type: string
+          description: The tool name
+      - juicer pre --version:
+          type: eval
+          description: The expression to obtain the version of the tool
+    - - ${task.process}:
+          type: string
+          description: The process the versions were collected from
+      - juicerc:
+          type: string
+          description: The tool name
+      - "1.2":
+          type: string
+          description: The expression to obtain the version of the tool
+authors:
+  - "@yumisims"
+maintainers:
+  - "@yumisims"

modules/sanger-tol/pretext/juicerc/tests/main.nf.test

@@ -0,0 +1,108 @@
+nextflow_process {
+
+    name "Test Process PRETEXT_JUICERC"
+    script "../main.nf"
+    process "PRETEXT_JUICERC"
+
+    tag "modules"
+    tag "modules_sangertol"
+    tag "pretext"
+    tag "pretext/juicerc"
+    tag "pretext/pretext2asm"
+
+    test("gfAmaRube1 - bin") {
+
+        setup {
+            run("PRETEXT_PRETEXT2ASM") {
+                script "../../pretext2asm/main.nf"
+                process {
+                    """
+                    input[0] = [
+                        [ id:'test' ],
+                        file(params.modules_testdata_base_path + 'Amanita_rubescens/assembly/gfAmaRube1.fa', checkIfExists: true)
+                    ]
+                    input[1] = file(params.modules_testdata_base_path + 'Amanita_rubescens/assembly/gfAmaRube1_pretext.agp', checkIfExists: true)
+                    """
+                }
+            }
+        }
+
+        when {
+            process {
+                """
+                input[0] = [
+                    [ id:'test' ],
+                    file(params.modules_testdata_base_path + 'Amanita_rubescens/assembly/gfAmaRube1.bin', checkIfExists: true)
+                ]
+                input[1] = PRETEXT_PRETEXT2ASM.out.correctedagp.map { meta, agp -> agp }
+                input[2] = file(params.modules_testdata_base_path + 'Amanita_rubescens/assembly/gfAmaRube1.fa.fai', checkIfExists: true)
+                """
+            }
+        }
+
+        then {
+            def pre_c_sizes = file(process.out.outlog.get(0)).readLines().findAll { it.contains('PRE_C_SIZE') }
+            assertAll(
+                { assert process.success },
+                { assert pre_c_sizes.size() > 0 },
+                { assert snapshot([
+                    alignment: process.out.alignment,
+                    pre_c_sizes: pre_c_sizes,
+                    versions_juicer_pre: process.out.versions_juicer_pre,
+                    versions_juicerc: process.out.versions_juicerc,
+                ]).match() }
+            )
+        }
+
+    }
+
+    test("gfAmaRube1 - bin - stub") {
+
+        options "-stub"
+
+        setup {
+            run("PRETEXT_PRETEXT2ASM") {
+                options "-stub"
+                script "../../pretext2asm/main.nf"
+                process {
+                    """
+                    input[0] = [
+                        [ id:'test' ],
+                        file(params.modules_testdata_base_path + 'Amanita_rubescens/assembly/gfAmaRube1.fa', checkIfExists: true)
+                    ]
+                    input[1] = file(params.modules_testdata_base_path + 'Amanita_rubescens/assembly/gfAmaRube1_pretext.agp', checkIfExists: true)
+                    """
+                }
+            }
+        }
+
+        when {
+            process {
+                """
+                input[0] = [
+                    [ id:'test' ],
+                    file(params.modules_testdata_base_path + 'Amanita_rubescens/assembly/gfAmaRube1.bin', checkIfExists: true)
+                ]
+                input[1] = PRETEXT_PRETEXT2ASM.out.correctedagp.map { meta, agp -> agp }
+                input[2] = file(params.modules_testdata_base_path + 'Amanita_rubescens/assembly/gfAmaRube1.fa.fai', checkIfExists: true)
+                """
+            }
+        }
+
+        then {
+            def pre_c_sizes = file(process.out.outlog.get(0)).readLines().findAll { it.contains('PRE_C_SIZE') }
+            assertAll(
+                { assert process.success },
+                { assert pre_c_sizes.isEmpty() },
+                { assert snapshot([
+                    alignment: process.out.alignment,
+                    pre_c_sizes: pre_c_sizes,
+                    versions_juicer_pre: process.out.versions_juicer_pre,
+                    versions_juicerc: process.out.versions_juicerc,
+                ]).match() }
+            )
+        }
+
+    }
+
+}