Add ReverseRegistrarShim

.github/workflows/test.yml

@@ -30,12 +30,11 @@ jobs:
       - name: Install Foundry
         uses: foundry-rs/foundry-toolchain@v1
         with:
-          version: nightly
+          version: stable
 
       - name: Run Forge build
         run: |
           forge --version
-          forge build --sizes
         id: build
 
       - name: Run Forge tests

src/L2/ReverseRegistrarShim.sol

@@ -0,0 +1,51 @@
+//SPDX-License-Identifier: MIT
+pragma solidity ^0.8.23;
+
+import {IReverseRegistrar} from "./interface/IReverseRegistrar.sol";
+import {IL2ReverseRegistrar} from "./interface/IL2ReverseRegistrar.sol";
+
+/// @title ReverseRegistrarShim
+///
+/// @notice A temporary shim contract used to ensure user data is not lost while migrating into ENSIP-19 compliance.
+///         The contract writes reverse records to both the legacy ReverseRegistrar and the new ENS-deployed
+///         L2ReverseRegistrar.
+///
+/// @author Coinbase (https://github.com/base/basenames)
+contract ReverseRegistrarShim {
+    /// @notice The address of the legacy Basenames ReverseRegistrar contract.
+    address public immutable reverseRegistrar;
+    /// @notice The address of the ENS-deployed L2ReverseRegistrar contract.
+    address public immutable l2ReverseRegistrar;
+    /// @notice The address of the Basenames public resolver.
+    address public immutable l2Resolver;
+
+    /// @notice constructor.
+    constructor(address reverseRegistrar_, address l2ReverseRegistrar_, address l2Resolver_) {
+        reverseRegistrar = reverseRegistrar_;
+        l2ReverseRegistrar = l2ReverseRegistrar_;
+        l2Resolver = l2Resolver_;
+    }
+
+    /// @notice Sets the reverse record `name` for `addr`.
+    ///
+    /// @dev First calls the ENS L2ReverseRegistrar and sets the name-record for the provided address. Then calls the legacy
+    ///     Basenames reverse registrar and registers the name there as well.
+    ///
+    /// @param addr The name records will be set for this address.
+    /// @param name The name that will be stored for `addr`.
+    /// @param signatureExpiry The timestamp expiration of the signature.
+    /// @param cointypes The array of networks-as-cointypes used in replayable reverse sets.
+    /// @param signature The signature bytes.
+    function setNameForAddrWithSignature(
+        address addr,
+        string calldata name,
+        uint256 signatureExpiry,
+        uint256[] memory cointypes,
+        bytes memory signature
+    ) external returns (bytes32) {
+        IL2ReverseRegistrar(l2ReverseRegistrar).setNameForAddrWithSignature(
+            addr, signatureExpiry, name, cointypes, signature
+        );
+        return IReverseRegistrar(reverseRegistrar).setNameForAddr(addr, msg.sender, l2Resolver, name);
+    }
+}

src/L2/interface/IL2ReverseRegistrar.sol

@@ -0,0 +1,48 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.4;
+
+/// @notice Interface for the L2 Reverse Registrar.
+interface IL2ReverseRegistrar {
+    /// @notice Sets the `nameForAddr()` record for the calling account.
+    ///
+    /// @param name The name to set.
+    function setName(string memory name) external;
+
+    /// @notice Sets the `nameForAddr()` record for the addr provided account.
+    ///
+    /// @param addr The address to set the name for.
+    /// @param name The name to set.
+    function setNameForAddr(address addr, string memory name) external;
+
+    /// @notice Sets the `nameForAddr()` record for the addr provided account using a signature.
+    ///
+    /// @param addr The address to set the name for.
+    /// @param name The name to set.
+    /// @param coinTypes The coin types to set. Must be inclusive of the coin type for the contract.
+    /// @param signatureExpiry Date when the signature expires.
+    /// @param signature The signature from the addr.
+    function setNameForAddrWithSignature(
+        address addr,
+        uint256 signatureExpiry,
+        string memory name,
+        uint256[] memory coinTypes,
+        bytes memory signature
+    ) external;
+
+    /// @notice Sets the `nameForAddr()` record for the contract provided that is owned with `Ownable`.
+    ///
+    /// @param contractAddr The address of the contract to set the name for (implementing Ownable).
+    /// @param owner The owner of the contract (via Ownable).
+    /// @param signatureExpiry The expiry of the signature.
+    /// @param name The name to set.
+    /// @param coinTypes The coin types to set. Must be inclusive of the coin type for the contract.
+    /// @param signature The signature of an address that will return true on isValidSignature for the owner.
+    function setNameForOwnableWithSignature(
+        address contractAddr,
+        address owner,
+        uint256 signatureExpiry,
+        string memory name,
+        uint256[] memory coinTypes,
+        bytes memory signature
+    ) external;
+}

test/ReverseRegistrarShim/ReverseRegistrarShimBase.t.sol

@@ -0,0 +1,35 @@
+//SPDX-License-Identifier: MIT
+pragma solidity ^0.8.23;
+
+import {Test} from "forge-std/Test.sol";
+import {ReverseRegistrarShim} from "src/L2/ReverseRegistrarShim.sol";
+import {MockReverseRegistrar} from "test/mocks/MockReverseRegistrar.sol";
+import {MockL2ReverseRegistrar} from "test/mocks/MockL2ReverseRegistrar.sol";
+import {MockPublicResolver} from "test/mocks/MockPublicResolver.sol";
+
+contract ReverseRegistrarShimBase is Test {
+    MockL2ReverseRegistrar l2RevReg;
+    MockReverseRegistrar revReg;
+    MockPublicResolver resolver;
+
+    ReverseRegistrarShim public shim;
+
+    address userA;
+    address userB;
+    string nameA = "userAName";
+    string nameB = "userBName";
+
+    uint256 signatureExpiry = 0;
+    bytes signature;
+    uint256[] cointypes;
+
+    function setUp() external {
+        l2RevReg = new MockL2ReverseRegistrar();
+        revReg = new MockReverseRegistrar();
+        resolver = new MockPublicResolver();
+        shim = new ReverseRegistrarShim(address(revReg), address(l2RevReg), address(resolver));
+
+        userA = makeAddr("userA");
+        userB = makeAddr("userB");
+    }
+}

test/ReverseRegistrarShim/SetNameForAddrWithSignature.t.sol

@@ -0,0 +1,29 @@
+//SPDX-License-Identifier: MIT
+pragma solidity ^0.8.23;
+
+import {ReverseRegistrarShimBase} from "./ReverseRegistrarShimBase.t.sol";
+import {MockL2ReverseRegistrar} from "test/mocks/MockL2ReverseRegistrar.sol";
+import {MockReverseRegistrar} from "test/mocks/MockReverseRegistrar.sol";
+
+contract SetNameForAddrWithSignature is ReverseRegistrarShimBase {
+    function test_setsNameForAddr_onReverseRegistrar() public {
+        vm.expectCall(
+            address(revReg),
+            abi.encodeCall(MockReverseRegistrar.setNameForAddr, (userA, userA, address(resolver), nameA))
+        );
+        vm.prank(userA);
+        shim.setNameForAddrWithSignature(userA, nameA, signatureExpiry, cointypes, signature);
+    }
+
+    function test_setsNameForAddr_onL2ReverseRegistrar() public {
+        vm.expectCall(
+            address(l2RevReg),
+            abi.encodeCall(
+                MockL2ReverseRegistrar.setNameForAddrWithSignature,
+                (userA, signatureExpiry, nameA, cointypes, signature)
+            )
+        );
+        vm.prank(userA);
+        shim.setNameForAddrWithSignature(userA, nameA, signatureExpiry, cointypes, signature);
+    }
+}

test/mocks/MockL2ReverseRegistrar.sol

@@ -0,0 +1,19 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.23;
+
+contract MockL2ReverseRegistrar {
+    /// @notice Sets the `nameForAddr()` record for the addr provided account using a signature.
+    ///
+    /// @param addr The address to set the name for.
+    /// @param name The name to set.
+    /// @param coinTypes The coin types to set. Must be inclusive of the coin type for the contract.
+    /// @param signatureExpiry Date when the signature expires.
+    /// @param signature The signature from the addr.
+    function setNameForAddrWithSignature(
+        address addr,
+        uint256 signatureExpiry,
+        string memory name,
+        uint256[] memory coinTypes,
+        bytes memory signature
+    ) external {}
+}

test/mocks/MockReverseResolver.sol

@@ -0,0 +1,12 @@
+//SPDX-License-Identifier: MIT
+pragma solidity ^0.8.23;
+
+contract MockReverseResolver {
+    function setNameForAddrWithSignature(address, string calldata, uint256, bytes memory)
+        external
+        view
+        returns (bytes32)
+    {
+        return bytes32(block.timestamp);
+    }
+}