feat: ✨ options for game version validation

addons/mod_loader/mod_loader_store.gd

@@ -177,6 +177,9 @@ func _update_ml_options_from_options_resource() -> void:
 		# Update from the options in the resource
 		ml_options = override_options
 
+		if not ml_options.customize_script_path.is_empty():
+			ml_options.customize_script_instance = load(ml_options.customize_script_path).new(ml_options)
+
 
 func _exit_tree() -> void:
 	# Save the cache to the cache file.

addons/mod_loader/options/example_customize_script.gd

@@ -0,0 +1,46 @@
+extends RefCounted
+
+# This is an example script for the ModLoaderOptionsProfile `customize_script_path`.
+# Ideally, place this script outside the `mod_loader` directory to simplify the update process.
+
+# This script is loaded after `mod_loader_store.ml_options` has been initialized.
+# It receives `ml_options` as an argument, allowing you to apply settings
+# that cannot be configured through the editor UI.
+func _init(ml_options: ModLoaderOptionsProfile) -> void:
+	# Use OS.has_feature() to apply changes only for specific platforms,
+	# or create multiple customization scripts and set their paths accordingly in the option profiles.
+	if OS.has_feature("Steam"):
+		pass
+	elif OS.has_feature("Epic"):
+		pass
+	else:
+		# Set `custom_game_version_validation_callable` to use a custom validation function.
+		ml_options.custom_game_version_validation_callable = custom_is_game_version_compatible
+
+# Custom validation function
+# See `ModManifest._is_game_version_compatible()` for the default validation logic.
+func custom_is_game_version_compatible(manifest: ModManifest) -> bool:
+	print("! ☞ﾟヮﾟ)☞ CUSTOM VALIDATION HERE ☜ﾟヮﾟ☜) !")
+
+	var mod_id := manifest.get_mod_id()
+
+	for version in manifest.compatible_game_version:
+		if not version == "pizza":
+			# Push a warning message displayed after manifest validation is complete.
+			manifest.validation_messages_warning.push_back(
+				"The mod \"%s\" may not be compatible with the current game version.
+				Enable at your own risk. (Current game version: %s, mod compatible with game versions: %s)" %
+				[mod_id, "MyGlobalVars.MyGameVersion", manifest.compatible_game_version]
+			)
+			return true
+
+		if not version == "pineapple":
+			# Push an error message displayed after manifest validation is complete.
+			manifest.validation_messages_error.push_back(
+				"The mod \"%s\" is incompatible with the current game version.
+				(Current game version: %s, mod compatible with game versions: %s)" %
+				[mod_id, "MyGlobalVars.MyGameVersion", manifest.compatible_game_version]
+			)
+			return false
+
+	return true

addons/mod_loader/resources/mod_manifest.gd

@@ -113,7 +113,14 @@ func validate(manifest: Dictionary, path: String) -> bool:
 	config_schema = ModLoaderUtils.get_dict_from_dict(godot_details, "config_schema")
 	steam_workshop_id = ModLoaderUtils.get_string_from_dict(godot_details, "steam_workshop_id")
 
-	_is_game_version_compatible(mod_id)
+	if ModLoaderStore.ml_options.game_version_validation == ModLoaderOptionsProfile.VERSION_VALIDATION.DEFAULT:
+		_is_game_version_compatible(mod_id)
+
+	if ModLoaderStore.ml_options.game_version_validation == ModLoaderOptionsProfile.VERSION_VALIDATION.CUSTOM:
+		if ModLoaderStore.ml_options.custom_game_version_validation_callable:
+			ModLoaderStore.ml_options.custom_game_version_validation_callable.call(self)
+		else:
+			ModLoaderLog.error("No custom game version validation callable detected. Please provide a valid validation callable.", LOG_NAME)
 
 	is_mod_id_array_valid(mod_id, dependencies, "dependency")
 	is_mod_id_array_valid(mod_id, incompatibilities, "incompatibility")

addons/mod_loader/resources/options_profile.gd

@@ -1,18 +1,74 @@
 class_name ModLoaderOptionsProfile
 extends Resource
+##
+## Class to define and store Mod Loader Options.
 
 
+## Settings for game version validation.
+enum VERSION_VALIDATION {
+	## Uses the default semantic versioning (semver) validation.
+	DEFAULT,
+
+	## Disables validation of the game version specified in [member semantic_version]
+	## and the mod's [member ModManifest.compatible_game_version].
+	DISABLED,
+
+	## Enables custom game version validation.
+	## Use [member customize_script_path] to specify a script that customizes the Mod Loader options.
+	## In this script, you must set [member custom_game_version_validation_callable]
+	## to a custom validation [Callable].
+	##
+	## Example:
+	## [codeblock]
+	## extends RefCounted
+	##
+	## func _init(ml_options: ModLoaderOptionsProfile) -> void:
+	##    # Assign a custom validation function.
+	##    # Use `OS.has_feature(feature_tag)` to apply different validations for different platforms.
+	##    ml_options.custom_game_version_validation_callable = custom_is_game_version_compatible
+	##
+	## func custom_is_game_version_compatible(manifest: ModManifest) -> bool:
+	##    print("! ☞ﾟヮﾟ)☞ CUSTOM VALIDATION HERE ☜ﾟヮﾟ☜) !")
+	##
+	##    var mod_id := manifest.get_mod_id()
+	##
+	##    for version in manifest.compatible_game_version:
+	##        if not version == "pizza":
+	##            manifest.validation_messages_warning.push_back(
+	##                "The mod \"%s\" may not be compatible with the current game version.
+	##                Enable at your own risk. (current game version: %s, mod compatible with game versions: %s)" %
+	##                [mod_id, MyGlobalVars.MyGameVersion, manifest.compatible_game_version]
+	##            )
+	##            return false
+	##
+	##    return true
+	## [/codeblock]
+	##
+	## Using a customization script allows you to keep your custom code outside the addon directory,
+	## making it easier to update the mod loader without affecting your modifications.
+	##
+	CUSTOM,
+}
+
 ## Can be used to disable mods for specific plaforms by using feature overrides
 @export var enable_mods: bool = true
 ## List of mod ids that can't be turned on or off
 @export var locked_mods: Array[String] = []
-
+## List of mods that will not be loaded
 @export var disabled_mods: Array[String] = []
 ## Disables the requirement for the mod loader autoloads to be first
 @export var allow_modloader_autoloads_anywhere: bool = false
-
+## This script is loaded after [member ModLoaderStore.ml_options] has been initialized.
+## It is instantiated with [member ModLoaderStore.ml_options] as an argument.
+## Use this script to apply settings that cannot be configured through the editor UI.
+##
+## For an example, see [enum VERSION_VALIDATION] [code]CUSTOM[/code] or
+## [code]res://addons/mod_loader/options/example_customize_script.gd[/code].
+@export_file var customize_script_path: String
 
 @export_group("Logging")
+## Sets the logging verbosity level.
+## Refer to [enum ModLoaderLog.VERBOSITY_LEVEL] for more details.
 @export var log_level := ModLoaderLog.VERBOSITY_LEVEL.DEBUG
 ## Stops the mod loader from logging any deprecation related errors.
 @export var ignore_deprecated_errors: bool = false
@@ -42,6 +98,7 @@ extends Resource
 ## Path to a folder containing mods [br]
 ## Mod zips should be directly in this folder
 @export_dir var override_path_to_mods = ""
+## Use this option to override the default path where configs are stored.
 @export_dir var override_path_to_configs = ""
 ## Path to a folder containing workshop items.[br]
 ## Mods zips are placed in another folder, usually[br]
@@ -61,3 +118,17 @@ extends Resource
 @export_dir var restart_notification_scene_path := "res://addons/mod_loader/restart_notification.tscn"
 ## Can be used to disable the mod loader's restart logic. Use the [signal ModLoader.new_hooks_created] to implement your own restart logic.
 @export var disable_restart := false
+
+@export_group("Mod Validation")
+## Defines how the game version should be validated.
+## This setting controls validation for the game version specified in [member semantic_version]
+## and the mod's [member ModManifest.compatible_game_version].
+@export var game_version_validation := VERSION_VALIDATION.DEFAULT
+
+## Callable that is executed during [ModManifest] validation
+## if [member game_version_validation] is set to [enum VERSION_VALIDATION] [code]CUSTOM[/code].
+## See the example under [enum VERSION_VALIDATION] [code]CUSTOM[/code] to learn how to set this up.
+var custom_game_version_validation_callable: Callable
+
+## Stores the instance of the script specified in [member customize_script_path].
+var customize_script_instance: RefCounted