Add deleteSMSmessage etc.. Update Example5

Author: PaulZC

examples/SARA-R5_Example5_ReceiveSMS/SARA-R5_Example5_ReceiveSMS.ino

@@ -39,8 +39,6 @@ SARA_R5 mySARA;
 // Change the pin number if required.
 //SARA_R5 mySARA(34);
 
-int previousUsed = 0; // Store the previous number of used memory locations
-
 void setup()
 {
   String currentOperator = "";
@@ -87,10 +85,16 @@ void setup()
     while (1)
       ; // Do nothing more
   }
+
+  while (Serial.available()) // Empty the serial RX buffer
+    Serial.read();
 }
 
 void loop()
 {
+  static bool printReadMessages = true; // Print all messages once. Then only print new messages. Unless a message is deleted.
+  static int previousUsed = -1; // Store the previous number of used memory locations
+  
   // Read the number of used and total messages
   int used;
   int total;
@@ -100,9 +104,9 @@ void loop()
   }
   else
   {
-    if (used > previousUsed) // Has a new message arrived?
+    if ((used != previousUsed) || printReadMessages) // Has a new message arrived? Or was the delete menu opened?
     {
-      Serial.print(F("Number of used memory locations: "));
+      Serial.print(F("\r\nNumber of used memory locations: "));
       Serial.println(used);
       Serial.print(F("Total number of memory locations: "));
       Serial.println(total);
@@ -118,11 +122,13 @@ void loop()
         String dateTime = "";
         String message = "";
         // Read the message from this location. Reading from empty message locations returns an ERROR
+        // unread can be: "REC UNREAD", "REC READ", "STO UNSENT", "STO SENT"
+        // If the location is empty, readSMSmessage will return a SARA_R5_ERROR_UNEXPECTED_RESPONSE
         if (mySARA.readSMSmessage(memoryLocation, &unread, &from, &dateTime, &message) == SARA_R5_SUCCESS)
         {
-          if (unread == "REC UNREAD") // Only print new (previously-unread) messages. Comment this line to display all messages.
+          if (printReadMessages || (unread == "REC UNREAD")) 
           {
-            Serial.print(F("Message index: "));
+            Serial.print(F("Message location: "));
             Serial.println(memoryLocation);
             Serial.print(F("Status: "));
             Serial.println(unread);
@@ -138,12 +144,129 @@ void loop()
         memoryLocation++; // Move on to the next memory location
       }
 
+      printReadMessages = false;
       previousUsed = used; // Update previousUsed
 
       Serial.println(F("Waiting for a new message..."));
       Serial.println();
+      Serial.println(F("Hit any key to delete a message..."));
+      Serial.println();
     }
   }
 
-  delay(5000); // Check for new messages every 5 seconds
+  int delayCount = 0;
+  while (delayCount < 5000)
+  {
+    delay(1); // Delay for five seconds, unless the user presses a key
+    delayCount++;
+
+    if (Serial.available())
+    {
+      Serial.println(F("To delete a single message:                        enter its location followed by LF / Newline"));
+      Serial.println(F("To delete all read messages:                       enter r followed by LF / Newline"));
+      Serial.println(F("To delete all read and sent messages:              enter s followed by LF / Newline"));
+      Serial.println(F("To delete all read, sent and unsent messages:      enter u followed by LF / Newline"));
+      Serial.println(F("To delete all messages, including unread messages: enter a followed by LF / Newline"));
+      Serial.println(F("To exit:                                           enter LF / Newline"));
+
+      Serial.read(); // Read and discard the char that opened the menu
+
+      int location = 0;
+      bool selected = false;
+      while (!selected)
+      {
+        while (!Serial.available()) ; // Wait for a character to arrive
+        char c = Serial.read(); // Read it
+        if (c == '\n') // Is it a LF?
+        {
+          if ((location >= 1) && (location <= total)) // Delete a single message at location
+          {
+            if (mySARA.deleteSMSmessage(location) == SARA_R5_SUCCESS)
+            {
+              Serial.println(F("\r\nMessage deleted!\r\n"));
+              printReadMessages = true;
+            }
+            else
+            {
+              Serial.println(F("\r\nMessage not deleted!\r\n"));
+            }
+          }
+          else if (location == 1001) // r
+          {
+            if (mySARA.deleteReadSMSmessages() == SARA_R5_SUCCESS)
+            {
+              Serial.println(F("\r\nRead messages deleted!\r\n"));
+              printReadMessages = true;
+            }
+            else
+            {
+              Serial.println(F("\r\nMessages not deleted!\r\n"));
+            }
+          }
+          else if (location == 1002) // s
+          {
+            if (mySARA.deleteReadSentSMSmessages() == SARA_R5_SUCCESS)
+            {
+              Serial.println(F("\r\nRead and sent messages deleted!\r\n"));
+              printReadMessages = true;
+            }
+            else
+            {
+              Serial.println(F("\r\nMessages not deleted!\r\n"));
+            }
+          }
+          else if (location == 1003) // u
+          {
+            if (mySARA.deleteReadSentUnsentSMSmessages() == SARA_R5_SUCCESS)
+            {
+              Serial.println(F("\r\nRead, sent and unsent messages deleted!\r\n"));
+              printReadMessages = true;
+            }
+            else
+            {
+              Serial.println(F("\r\nMessages not deleted!\r\n"));
+            }
+          }
+          else if (location == 1004) // a
+          {
+            if (mySARA.deleteAllSMSmessages() == SARA_R5_SUCCESS)
+            {
+              Serial.println(F("\r\nAll messages deleted!\r\n"));
+              printReadMessages = true;
+            }
+            else
+            {
+              Serial.println(F("\r\nMessages not deleted!\r\n"));
+            }
+          }
+          else
+            Serial.println(F("\r\nExit...\r\n"));
+          selected = true;
+        }
+        else if ((c >= '0') && (c <= '9'))
+        {
+          location *= 10; // Multiply by 10
+          location += c - '0'; // Add the digit
+        }
+        else if (c == 'r')
+        {
+          location = 1001;
+        }
+        else if (c == 's')
+        {
+          location = 1002;
+        }
+        else if (c == 'u')
+        {
+          location = 1003;
+        }
+        else if (c == 'a')
+        {
+          location = 1004;
+        }
+      }
+
+      delayCount = 5000;
+    }
+  }
 }

keywords.txt

@@ -97,6 +97,11 @@ setSMSMessageFormat	KEYWORD2
 sendSMS	KEYWORD2
 getPreferredMessageStorage	KEYWORD2
 readSMSmessage	KEYWORD2
+deleteSMSmessage	KEYWORD2
+deleteReadSMSmessages	KEYWORD2
+deleteReadSentSMSmessages	KEYWORD2
+deleteReadSentUnsentSMSmessages	KEYWORD2
+deleteAllSMSmessages	KEYWORD2
 setBaud	KEYWORD2
 setFlowControl	KEYWORD2
 setGpioMode	KEYWORD2

src/SparkFun_u-blox_SARA-R5_Arduino_Library.cpp

@@ -1886,7 +1886,7 @@ SARA_R5_error_t SARA_R5::getPreferredMessageStorage(int *used, int *total, Strin
   {
     if (_printDebug == true)
     {
-      _debugPort->print(F("getPreferredMessageStorage: memory: "));
+      _debugPort->print(F("getPreferredMessageStorage: memory1 (read and delete): "));
       _debugPort->print(memory);
       _debugPort->print(F(" used: "));
       _debugPort->print(u);
@@ -2010,6 +2010,25 @@ SARA_R5_error_t SARA_R5::readSMSmessage(int location, String *unread, String *fr
   return err;
 }
 
+SARA_R5_error_t SARA_R5::deleteSMSmessage(int location, int deleteFlag)
+{
+  char *command;
+  SARA_R5_error_t err;
+
+  command = sara_r5_calloc_char(strlen(SARA_R5_DELETE_MESSAGE) + 12);
+  if (command == NULL)
+    return SARA_R5_ERROR_OUT_OF_MEMORY;
+  if (deleteFlag == 0)
+    sprintf(command, "%s=%d", SARA_R5_DELETE_MESSAGE, location);
+  else
+    sprintf(command, "%s=%d,%d", SARA_R5_DELETE_MESSAGE, location, deleteFlag);
+
+  err = sendCommandWithResponse(command, SARA_R5_RESPONSE_OK, NULL, SARA_R5_55_SECS_TIMEOUT);
+
+  free(command);
+  return err;
+}
+
 SARA_R5_error_t SARA_R5::setBaud(unsigned long baud)
 {
   SARA_R5_error_t err;

src/SparkFun_u-blox_SARA-R5_Arduino_Library.h

@@ -78,6 +78,7 @@
 // Timing
 #define SARA_R5_STANDARD_RESPONSE_TIMEOUT 1000
 #define SARA_R5_10_SEC_TIMEOUT 10000
+#define SARA_R5_55_SECS_TIMEOUT 55000
 #define SARA_R5_2_MIN_TIMEOUT 120000
 #define SARA_R5_3_MIN_TIMEOUT 180000
 #define SARA_R5_SET_BAUD_TIMEOUT 500
@@ -122,6 +123,7 @@ const char SARA_R5_SEND_TEXT[] = "+CMGS";          // Send SMS message
 const char SARA_R5_NEW_MESSAGE_IND[] = "+CNMI";    // New [SMS] message indication
 const char SARA_R5_PREF_MESSAGE_STORE[] = "+CPMS"; // Preferred message storage
 const char SARA_R5_READ_TEXT_MESSAGE[] = "+CMGR";  // Read message
+const char SARA_R5_DELETE_MESSAGE[] = "+CMGD";     // Delete message
 // V24 control and V25ter (UART interface)
 const char SARA_R5_FLOW_CONTROL[] = "&K";   // Flow control
 const char SARA_R5_COMMAND_BAUD[] = "+IPR"; // Baud rate
@@ -599,6 +601,11 @@ class SARA_R5 : public Print
   SARA_R5_error_t sendSMS(String number, String message);
   SARA_R5_error_t getPreferredMessageStorage(int *used, int *total, String memory = "ME");
   SARA_R5_error_t readSMSmessage(int location, String *unread, String *from, String *dateTime, String *message);
+  SARA_R5_error_t deleteSMSmessage(int location, int deleteFlag = 0); // Default to deleting the single message at the specified location
+  SARA_R5_error_t deleteReadSMSmessages(void)           { return (deleteSMSmessage( 1, 1 )); }; // Delete all the read messages from preferred storage
+  SARA_R5_error_t deleteReadSentSMSmessages(void)       { return (deleteSMSmessage( 1, 2 )); }; // Delete the read and sent messages from preferred storage
+  SARA_R5_error_t deleteReadSentUnsentSMSmessages(void) { return (deleteSMSmessage( 1, 3 )); }; // Delete the read, sent and unsent messages from preferred storage
+  SARA_R5_error_t deleteAllSMSmessages(void)            { return (deleteSMSmessage( 1, 4 )); }; // Delete the read, sent, unsent and unread messages from preferred storage
 
   // V24 Control and V25ter (UART interface) AT commands
   SARA_R5_error_t setBaud(unsigned long baud);