feat: up and running with fish. this is groovy.

Author: samandmoore

.gitignore

@@ -8,3 +8,6 @@ vim/.netrwhist
 
 # have to ignore this file because we symlink the whole nvim directory to ~
 config/nvim/lua/plugins/colorscheme.lua
+
+# fish local overrides
+config/fish/local.fish

config/fish/conf.d/aliases.fish

@@ -0,0 +1,39 @@
+# Easier navigation
+abbr --add .. cd ..
+abbr --add ... cd ../..
+abbr --add .... cd ../../..
+abbr --add ..... cd ../../../..
+
+# Enable aliases to be sudo'ed
+alias sudo 'sudo '
+
+# Get week number
+abbr --add week date +%V
+
+# Clean up LaunchServices to remove duplicates in the "Open With" menu
+abbr --add lscleanup /System/Library/Frameworks/CoreServices.framework/Frameworks/LaunchServices.framework/Support/lsregister -kill -r -domain local -domain system -domain user '&&' killall Finder
+
+# View HTTP traffic
+abbr --add sniff sudo ngrep -d en0 -t "'^(GET|POST) '" "'tcp and port 80'"
+abbr --add httpdump sudo tcpdump -i en1 -n -s 0 -w - '|' grep -a -o -E "\"Host\\: .*|GET \\/.*\""
+
+# Canonical hex dump; some systems have this symlinked
+if not command --query hd
+    abbr --add hd hexdump -C
+end
+
+# macOS has no md5sum, so use md5 as a fallback
+if not command --query md5sum
+    abbr --add md5sum md5
+end
+
+# macOS has no sha1sum, so use shasum as a fallback
+if not command --query sha1sum
+    abbr --add sha1sum shasum
+end
+
+# bundle exec
+abbr --add be bundle exec
+
+# kubectl
+abbr --add k kubectl

config/fish/conf.d/exports.fish

@@ -0,0 +1,22 @@
+# Make nvim the default editor
+set --global --export EDITOR nvim
+
+# Prefer US English and use UTF-8
+set --global --export LANG en_US.UTF-8
+set --global --export LC_ALL en_US.UTF-8
+
+# Highlight section titles in manual pages
+set --global --export LESS_TERMCAP_md (set_color --bold; set_color yellow)
+
+# Don't clear the screen after quitting a manual page
+set --global --export MANPAGER "less -X"
+
+# FZF search command
+set --global --export FZF_DEFAULT_COMMAND 'rg --files --hidden --glob "!.git/*"'
+
+# Attempt to have bat use terminal theme
+set --global --export BAT_THEME ansi
+
+# Add ~/.bin and ~/.local/bin to PATH
+fish_add_path --global ~/.bin
+fish_add_path --global ~/.local/bin

config/fish/config.fish

@@ -0,0 +1,64 @@
+# Only run in interactive shells
+status is-interactive; or return
+
+set --global fish_greeting ""
+
+if test -f /opt/homebrew/bin/brew
+    /opt/homebrew/bin/brew shellenv | source
+end
+
+if type --query mise
+    mise activate fish | source
+end
+
+if type --query starship
+    starship init fish | source
+end
+
+if command --query zoxide
+    zoxide init --cmd j fish | source
+end
+
+if type --query fzf
+    fzf --fish | source
+end
+
+# eza / ls
+if type --query eza
+    alias ls eza
+    alias l 'eza --long'
+    alias la 'eza --long --all'
+    alias lt 'eza --tree'
+    alias tree 'eza --tree --level=2'
+else
+    alias l 'ls -l'
+    alias la 'ls -la'
+end
+
+# fancy cat
+if type --query bat
+    alias cat 'bat --paging=never --style=plain'
+end
+
+# lazier git
+if type --query lazygit
+    abbr --add lg lazygit
+end
+
+# use nvim for vim if it's there
+if command --query nvim
+    alias vim nvim
+    alias vi nvim
+    alias e nvim
+    alias v nvim
+end
+
+# Set terminal title to current directory
+function fish_title
+    string replace $HOME '~' $PWD
+end
+
+# Source local overrides if they exist
+if test -f ~/.config/fish/local.fish
+    source ~/.config/fish/local.fish
+end

config/fish/functions/allthecolors.fish

@@ -0,0 +1,9 @@
+function allthecolors --description 'Print all 256 terminal colors'
+    set --local reset (tput op)
+    set --local width (math $COLUMNS - 6)
+    set --local bar (string repeat --count $width '=')
+    for i in (seq 0 256)
+        set --local num (string pad --width 3 --char 0 $i)
+        echo -e "$num $(tput setaf $i; tput setab $i)$bar$reset"
+    end
+end

config/fish/functions/diff.fish

@@ -0,0 +1,3 @@
+function diff --wraps='git diff' --description 'Use git diff for colored word diffs'
+    git diff --no-index --color-words $argv
+end

config/fish/functions/pg_kill_db.fish

@@ -0,0 +1,3 @@
+function pg_kill_db --argument-names db --description 'Kill all connections to a given PostgreSQL database'
+    psql -d $db -c "select pg_terminate_backend(pg_stat_activity.pid) from pg_stat_activity where pg_stat_activity.datname = '$db' and pid <> pg_backend_pid();"
+end

config/kitty/kitty.conf

@@ -28,7 +28,6 @@ enabled_layouts splits:split_axis=vertical,stack
 map ctrl+a>v launch --location=vsplit --cwd=current
 map ctrl+a>s launch --location=hsplit --cwd=current
 
-# shell bash
 shell_integration disabled
 allow_remote_control yes
 listen_on unix:/tmp/mykitty

config/kitty/macos.conf

@@ -1,2 +1,3 @@
 font_family      family='CaskaydiaMono Nerd Font Mono' postscript_name=CaskaydiaMonoNFM-Regular
 font_size 17.0
+shell /opt/homebrew/bin/fish

script/setup_macos.sh

@@ -12,9 +12,9 @@ function setup_shell() {
     echo '/opt/homebrew/bin/fish' | sudo tee -a /etc/shells
   fi
 
-  if [[ "$SHELL" != '/opt/homebrew/bin/bash' ]]; then
-    echo 'Current shell is not homebrew bash, switching...'
-    chsh -s /opt/homebrew/bin/bash
+  if [[ "$SHELL" != '/opt/homebrew/bin/fish' ]]; then
+    echo 'Current shell is not homebrew fish, switching...'
+    chsh -s /opt/homebrew/bin/fish
   fi
 }