reqstool-java-gradle-plugin/build.gradle at main · reqstool/reqstool-java-gradle-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
plugins {
    id 'java-gradle-plugin'
    id 'java-library'
    id 'maven-publish'
    id 'io.spring.javaformat' version '0.0.47'
    id 'com.gradle.plugin-publish' version '2.1.1'
    id 'pl.allegro.tech.build.axion-release' version '1.21.2'
}

scmVersion {
    tag {
        prefix = ''
    }
    versionCreator 'simple'
}

group = 'io.github.reqstool'
version = scmVersion.version

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

repositories {
    mavenCentral()
}

gradlePlugin {
    website = 'https://reqstool.github.io'
    vcsUrl = 'https://github.com/reqstool/reqstool-java-gradle-plugin.git'

    plugins {
        reqstoolPlugin {
            id = 'io.github.reqstool.gradle-plugin'
            implementationClass = 'io.github.reqstool.gradle.RequirementsToolPlugin'
            displayName = 'Reqstool Gradle Plugin'
            description = 'Gradle plugin for assembling and attaching reqstool ZIP artifacts'
            tags.set(['reqstool', 'requirements', 'verification', 'testing'] )
        }
    }
}

dependencies {
    // Jackson for YAML processing
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.22.0'
    implementation 'com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.22.0'

    // SnakeYAML for reqstool_config.yml generation
    implementation 'org.yaml:snakeyaml:2.6'

    // reqstool dogfooding: @Requirements/@SVCs annotations + processor
    implementation 'io.github.reqstool:reqstool-java-annotations:1.0.0'
    annotationProcessor 'io.github.reqstool:reqstool-java-annotations:1.0.0'
    testImplementation 'io.github.reqstool:reqstool-java-annotations:1.0.0'
    testAnnotationProcessor 'io.github.reqstool:reqstool-java-annotations:1.0.0'

    // Testing - JUnit BOM for version management
    testImplementation platform('org.junit:junit-bom:6.1.1')
    testImplementation 'org.junit.jupiter:junit-jupiter-api'
    testImplementation 'org.junit.jupiter:junit-jupiter-params'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

test {
    useJUnitPlatform()
}

publishing {
    publications {
        withType(MavenPublication) {
            pom {
                developers {
                    developer {
                        name = 'Reqstool Contributors'
                        organization = 'reqstool'
                        organizationUrl = 'https://github.com/reqstool'
                    }
                }
            }
        }
    }
}