git-intent/flake.nix at next · offlegacy/git-intent · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
{
  description = "A Nix-flake-based Node.js development environment";

  inputs.nixpkgs.url = "https://flakehub.com/f/NixOS/nixpkgs/0.1";

  outputs =
    inputs:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forEachSupportedSystem =
        f:
        inputs.nixpkgs.lib.genAttrs supportedSystems (
          system:
          f {
            pkgs = import inputs.nixpkgs {
              inherit system;
              overlays = [ inputs.self.overlays.default ];
            };
          }
        );
    in
    {
      overlays.default =
        final: prev:
        let
          packageJson =
            if builtins.pathExists ./package.json then
              builtins.fromJSON (builtins.readFile ./package.json)
            else
              { };
          packageManagerSpec = packageJson.packageManager or "pnpm@latest";

          parsePnpmVersion =
            spec:
            let
              matchResult = builtins.match "pnpm@(.*)" spec;
            in
            if matchResult != null then builtins.head matchResult else null;

          pnpmVersion = parsePnpmVersion packageManagerSpec;
        in
        rec {
          nodejs = prev.nodejs;
          yarn = (prev.yarn.override { inherit nodejs; });

          pnpm =
            if pnpmVersion != null then
              prev.pnpm.overrideAttrs (old: rec {
                version = pnpmVersion;
                src = prev.fetchurl {
                  url = "https://registry.npmjs.org/pnpm/-/pnpm-${version}.tgz";
                  hash = "sha256-hHIWjD4f0L/yh+aUsFP8y78gV5o/+VJrYzO+q432Wo0=";
                };
              })
            else
              prev.pnpm;
        };

      devShells = forEachSupportedSystem (
        { pkgs }:
        {
          default = pkgs.mkShell {
            packages = with pkgs; [
              node2nix
              nodejs
              pnpm
              yarn
            ];
          };
        }
      );
    };
}