mosoo/justfile at main · langgenius/mosoo · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
# List human-facing repository commands.
default:
    just --list

# Prepare a new checkout for local development.
setup:
    git submodule update --init
    bun install --frozen-lockfile
    just env-init
    just hooks-install
    just db-migrate

# Create or complete local development environment variables.
env-init:
    bun run env:init

# Install repository-managed Git hooks.
hooks-install:
    bun run hooks:install

# Check commit metadata on the current branch against origin/main.
commit-check:
    bun run commit:check

# Start the local development stack after applying local migrations.
dev:
    just db-migrate
    bun run dev

# Format repository files.
fmt:
    bun run fmt

# Check repository formatting without writing changes.
fmt-check:
    bun run fmt:check

# Check Markdown/MDX local links and image references.
docs-check:
    bun run docs:check

# Check formatting for one file or directory.
fmt-check-path path:
    bun run fmt:check:path -- "{{ path }}"

# Lint the repository.
lint: fmt-check
    bun run lint

# Type-check the repository.
tc: lint
    bun run tc

# Type-check one workspace package.
tc-package package:
    bun run --filter "{{ package }}" tc

# Run the regular test suite.
test: lint
    bun run test

# Test one workspace package.
test-package package:
    bun run --filter "{{ package }}" test

# Run one Bun test file.
test-file path:
    bun test "{{ path }}"

# Run the full repository verification gate.
check:
    bun run check

# Build the repository.
build: check
    bun run build

# Regenerate GraphQL outputs.
graphql-codegen:
    bun run graphql:codegen

# Check that GraphQL generated outputs are current.
graphql-codegen-check:
    bun run graphql:codegen:check

# Generate one append-only Drizzle migration. Pass --custom for data-only SQL.
db-generate name *args:
    bun run --filter @mosoo/db db:generate -- --name "{{ name }}" {{args}}

# Apply pending migrations to the existing local D1 state.
db-migrate:
    bun run db:migrate:local

# Explicitly destroy local API D1 state, then apply the migration chain.
db-reset-local:
    rm -rf apps/api/.wrangler/state/v3/d1
    just db-migrate

# Generate Cloudflare binding types.
cf-types:
    bun run cf:types

# Find unused dependencies and exports.
knip:
    bun run knip

# Run React Doctor.
react-doctor:
    bun run react-doctor

# Run React Doctor against the current diff.
react-doctor-diff:
    bun run react-doctor:diff

# Write the React Doctor JSON report.
react-doctor-report:
    bun run react-doctor:report

# Regenerate the help documentation index.
help-docs-index:
    bun run help-docs-index

# Run E2E cases. Use `just e2e --help`.
e2e *args:
    bun run e2e -- {{args}}

# Verify the Agent Driver submodule cutover.
driver-submodule-smoke:
    bun run driver:submodule:smoke

# Update the Agent Driver submodule to upstream HEAD.
driver-update:
    git submodule update --init --remote --checkout apps/driver

# Deploy API and Web production targets.
deploy: check
    bun run deploy

# Deploy the API production target.
deploy-api:
    bun run deploy:api

# Deploy the Web production target.
deploy-web:
    bun run deploy:web

# Remove generated local build and dependency directories.
clean:
    fd -u -t d -F node_modules . -X rm -rf
    fd -u -t d -F dist . -X rm -rf
    fd -u -t d -F .tmp . -X rm -rf
    fd -u -t d -F .angular . -X rm -rf