pullomatic/flake.nix at master · fooker/pullomatic · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
{
  description = "pullomatic - automated git pulls";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    flake-utils.url = "github:numtide/flake-utils";

    pre-commit-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
  };

  outputs = { self, nixpkgs, flake-utils, pre-commit-hooks, ... }:
    (flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

      in
      {
        checks = {
          inherit (self.packages.${system}) pullomatic;

          pre-commit-check = pre-commit-hooks.lib.${system}.run {
            src = ./.;

            hooks = {
              nixpkgs-fmt.enable = true;

              clippy = {
                enable = true;
                settings.allFeatures = true;
              };

              cargo-check = {
                enable = true;
              };

              rustfmt = {
                enable = true;
              };
            };
          };
        };

        packages = {
          pullomatic = pkgs.callPackage ./package.nix { };
          default = self.packages.${system}.pullomatic;
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = [ self.packages.${system}.pullomatic ]
          ++ self.checks.${system}.pre-commit-check.enabledPackages;

          packages = with pkgs; [
            cargo-deny
            cargo-outdated
            cargo-machete

            rustfmt
            clippy

            codespell

            nodejs
          ];

          inherit (self.checks.${system}.pre-commit-check) shellHook;

          RUST_BACKTRACE = 1;
          #RUST_SRC_PATH = "${pkgs.rust}/lib.rs/rustlib/src/rust/library";
        };
      })
    ) // {
      nixosModules = {
        pullomatic = ./module.nix;
        default = self.nixosModules.pullomatic;
      };
    };
}