openvino-notes/build.gradle.kts at main · embedded-dev-research/openvino-notes · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
import com.android.build.api.dsl.ApplicationExtension
import com.android.build.api.dsl.CommonExtension
import com.android.build.api.dsl.LibraryExtension
import io.gitlab.arturbosch.detekt.Detekt
import io.gitlab.arturbosch.detekt.extensions.DetektExtension
import kotlinx.kover.gradle.plugin.dsl.KoverProjectExtension
import org.jlleitschuh.gradle.ktlint.KtlintExtension

// Top-level build file where you can add configuration options common to all sub-projects/modules.
plugins {
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.kotlin.compose) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.kotlin.serialization) apply false
    alias(libs.plugins.ktlint)
    alias(libs.plugins.detekt)
    alias(libs.plugins.kover)
    id("com.google.gms.google-services") version "4.4.4" apply false
}

configure<KtlintExtension> {
    android.set(true)
    ignoreFailures.set(false)
    outputToConsole.set(true)
}

configure<DetektExtension> {
    buildUponDefaultConfig = true
    config.setFrom(files("$rootDir/detekt.yml"))
    basePath = rootDir.absolutePath
}

tasks.withType<Detekt>().configureEach {
    reports {
        html.required.set(true)
        md.required.set(false)
        sarif.required.set(true)
        txt.required.set(false)
        xml.required.set(true)
    }
}

kover {
    reports {
        filters {
            excludes {
                classes(
                    "*.BuildConfig",
                    "*.Manifest*",
                    "*.R",
                    "*.R$*",
                    "com.itlab.notes.App*",
                    "com.itlab.notes.MainActivity*",
                    "com.itlab.notes.di.*",
                    "com.itlab.notes.ui.editor.*",
                    "com.itlab.notes.ui.notes.*",
                    "com.itlab.notes.ui.theme.*",
                )
            }
        }
        verify {
            rule {
                minBound(60)
            }
        }
    }
}

subprojects {
    apply(plugin = "org.jlleitschuh.gradle.ktlint")
    apply(plugin = "io.gitlab.arturbosch.detekt")
    apply(plugin = "org.jetbrains.kotlinx.kover")

    dependencyLocking {
        lockAllConfigurations()
    }

    configure<KtlintExtension> {
        android.set(true)
        ignoreFailures.set(false)
        outputToConsole.set(true)
    }

    configure<DetektExtension> {
        buildUponDefaultConfig = true
        config.setFrom(rootProject.files("detekt.yml"))
        basePath = rootDir.absolutePath
    }

    configure<KoverProjectExtension> {
        reports {
            filters {
                excludes {
                    classes(
                        "*.BuildConfig",
                        "*.Manifest*",
                        "*.R",
                        "*.R$*",
                        "com.itlab.notes.App*",
                        "com.itlab.notes.MainActivity*",
                        "com.itlab.notes.di.*",
                        "com.itlab.notes.ui.editor.*",
                        "com.itlab.notes.ui.notes.*",
                        "com.itlab.notes.ui.theme.*",
                    )
                }
            }
            verify {
                rule {
                    minBound(60)
                }
            }
        }
    }

    tasks.withType<Detekt>().configureEach {
        jvmTarget = "21"
        reports {
            html.required.set(true)
            md.required.set(false)
            sarif.required.set(true)
            txt.required.set(false)
            xml.required.set(true)
        }
    }

    pluginManager.withPlugin("com.android.application") {
        extensions.configure<ApplicationExtension> {
            configureAndroidLint()
        }
    }

    pluginManager.withPlugin("com.android.library") {
        extensions.configure<LibraryExtension> {
            configureAndroidLint()
        }
    }

    if (name == "app") {
        tasks.matching { it.name == "koverVerify" }.configureEach {
            enabled = false
        }
    }
}

fun CommonExtension.configureAndroidLint() {
    lint.apply {
        abortOnError = true
        checkAllWarnings = true
        checkDependencies = true
        checkTestSources = true
        htmlReport = true
        lintConfig = rootProject.file("lint.xml")
        warningsAsErrors = true
        xmlReport = true
    }
}