evil: make minibuffer evilification optional

[Atemu]

I confirm that...

• I have searched the issue tracker, documentation, FAQ, Discourse, and Google, in case this issue has already been reported/resolved.

• I have read "How to Debug Issues", and will use it to provide as much information about this issue as possible.

• The issue can be reproduced on the latest available commit of Doom.

• The issue can be reproduced on a stable release of Emacs, such as 27, 28, or 29. (Unstable versions end in .50, .60, or .9x)

Expected behavior

I do not want my minibuffer evilifed but I do want +everywhere for major modes. There should be an option to leave the default key binds unmodified (e.g. +minibuffer).

I generally only want major mode evilification and leader keys.

Current behavior

Upstream evil-collection has evil-collection-setup-minibuffer for configuring that aspect but doom-emacs overrides it unconditionally:

https://github.com/doomemacs/doomemacs/blob/5f5a163c49207a7083ab1ecc9e78d268fd6600b8/modules/config/default/%2Bevil-bindings.el#L7-L34

Doom should either respect the upstream variable or have its own variable.

Related issue:

#6325

Steps to reproduce

1. Open Emacs
2. Want evil major modes and leader keys but default keybinds everywhere else
3. Find no option to configure it

System Information

https://pastebin.com/z6czCYHp

[real-or-random]

I haven't done any testing, but I don't understand this issue:

Upstream evil-collection has evil-collection-setup-minibuffer for configuring that aspect but doom-emacs overrides it unconditionally:

doomemacs/modules/config/default/+evil-bindings.el

doom doesn't override evil-collection-setup-minibuffer anywhere. If you don't enable it in your config manually, then it should be nil. Or are you saying you don't like the quoted bindings that are added unconditionally? If yes, why? Do they conflict with other bindings?

---

Independently of this, a separate +minibuffer option could be nice. It could set both evil-want-minibuffer and evil-collection-setup-minibuffer.

A LLM-generated summary that explains me the difference between the variables

evil-want-minibuffer (defined in evil-vars.el):

(defcustom evil-want-minibuffer nil
  "Whether to enable Evil in minibuffer(s)."
  :type 'boolean
  :group 'evil
  :set #'(lambda (sym value)
           (set-default sym value)
           (if value
               (add-hook 'minibuffer-setup-hook 'evil-initialize)
             (remove-hook 'minibuffer-setup-hook 'evil-initialize))))

The :set handler adds evil-initialize to minibuffer-setup-hook. And evil-initialize (evil-core.el) has this guard:

(defun evil-initialize ()
  (if evil-local-mode
      (evil-initialize-state)
    (or (and (minibufferp) (not evil-want-minibuffer))
        (evil-disabled-buffer-p)
        (evil-local-mode))))

So evil-want-minibuffer does two things:

1. Adds evil-initialize to minibuffer-setup-hook (via :set), so evil-local-mode gets activated in minibuffers.
2. Acts as a runtime guard: even if evil-initialize runs in a minibuffer, it won't enable evil unless evil-want-minibuffer is t.

The result: you get evil-mode (normal/insert state transitions) in minibuffers, but with no special keybindings. You just get the default evil keymaps.

---

evil-collection-setup-minibuffer (defined in evil-collection.el) does two separate things:

Thing 1: At evil-collection--supported-modes definition time, it conditionally includes minibuffer in the mode list:

    ,@(when evil-collection-setup-minibuffer '(minibuffer))

This causes evil-collection-init to call evil-collection-minibuffer-setup, which (modes/minibuffer/evil-collection-minibuffer.el):

• Binds <escape> → abort-recursive-edit, RET → exit-minibuffer, c → a minibuffer-safe change operator in normal state across all minibuffer keymaps.
• Adds evil-collection-minibuffer-insert to minibuffer-setup-hook, which forces insert state on minibuffer entry (so you start typing immediately).
• Sets up ex-completion bindings (C-p/C-n for history navigation).

Thing 2: It acts as a flag checked by per-mode setup functions (vertico, ivy, selectrum, etc.). Each of those wraps its minibuffer-specific bindings in:

(defvar evil-collection-setup-minibuffer)
(when evil-collection-setup-minibuffer
  ;; mode-specific minibuffer bindings (j/k, gg/G, C-d, etc.)
  ...)

For example, evil-collection-vertico-setup only binds j/k/gg/G/C-d/C-n/C-p in vertico-map when this flag is t.

---

The overlap / dependency you suspected:

evil-collection-setup-minibuffer does not set evil-want-minibuffer for you. They are independent. But evil-collection-minibuffer-setup hooks evil-collection-minibuffer-insert into minibuffer-setup-hook, which calls (evil-insert 1). This implicitly activates evil-local-mode in the minibuffer as a side effect of entering insert state — effectively doing what evil-want-minibuffer does, but through a different mechanism.

So in practice:

• evil-collection-setup-minibuffer alone (without evil-want-minibuffer): Works mostly. evil-collection's hook forces evil-insert, which activates evil-local-mode. But you'll hit the guard in evil-initialize — if some other code path calls evil-initialize in a minibuffer, it'll bail because evil-want-minibuffer is nil.
• evil-want-minibuffer alone (without evil-collection-setup-minibuffer): Evil activates in minibuffers but you get no curated keybindings (no j/k in normal mode, no starting in insert state, no vertico/ivy integration).
• Both: Clean. evil-want-minibuffer ensures evil activates properly via the intended code path; evil-collection-setup-minibuffer layers on the useful keybindings and insert-on-entry behavior.

Set both.

[real-or-random]

Independently of this, a separate +minibuffer option could be nice. It could set both evil-want-minibuffer and evil-collection-setup-minibuffer.

I tried evil-want-minibuffer but it's not great because it means you need to press ESC twice now to abort in the minibuffer.. For now I've settled on this for my personal config if anyone is interested.

;; evil-toggle-key (C-z) enables evil in the minibuffer.
;;
;; Alternatives:
;;   1. Always enable evil in the minibuffer
;;          (setopt evil-want-minibuffer t)
;;      This is annoying because we have to press ESC (or "fd") twice to abort:
;;      once to switch to normal state and once to quit the minibuffer.
;;   2. Like 1 but also default to emacs state in the minibuffer.
;;          (setopt evil-want-minibuffer t)
;;          (add-to-list 'evil-emacs-state-modes 'minibuffer-mode)
;;          ;; also in inactive mode for performance to avoid constant switching
;;          (add-to-list 'evil-emacs-state-modes 'minibuffer-inactive-mode)
;;      Then we only need to press ESC once to quit. But this is annoying due to
;;      issues with the cursor color:
;;         - The cursor will have a "warning" color in the minibuffer which is
;;           not elegant.
;;         - Actually, the color isn't even consistent due to a bug in evil, see
;;           my PR https://github.com/emacs-evil/evil/pull/2008.
;;         - When switching from the minibuffer to the main buffer, the cursor
;;           can sometimes stay in warning color for a short time, which is
;;           distracting.
(setopt evil-collection-setup-minibuffer t)
(after! evil
  ;; Ensure evil is initially off in the minibuffer
  (add-hook! 'minibuffer-setup-hook
             ;; PERF skip some lisp when this is already disabled. overkill?
             (when evil-local-mode
               (evil-local-mode -1)))
  ;; Sacrifice the current C-z binding (undo or helm-select-action).
  (undefine-key! :keymaps +default-minibuffer-maps evil-toggle-key)
  ;; evil-normal-state will enable evil in the buffer automatically
  (define-key! :keymaps +default-minibuffer-maps evil-toggle-key #'evil-normal-state)
  ;; TODO Should 'evil-ex-completion-map be added to +default-minibuffer-maps if
  ;;      evil is enabled? See also the C-s binding in config/default module.
  (define-key! :keymaps 'evil-ex-completion-map evil-toggle-key #'evil-normal-state))

(edit: made sure that evil is initially off)

My suggestion is to add a +minibuffer option that should be enabled by default that does the following:

• Do the minibuffer evil key bindings in +evil-bindings.el (which are currently done unconditionally)
• Set evil-collection-setup-minibuffer t
• Optionally integrate what my snippet does (this could also be done independently)

[LemonBreezes]

I agree the minibuffer Evil keybindings should be optional. Personally, I disable them and roll my own keybindings in the minibuffer as well.