Add a simple cmake build system

This is the initial part of a CMake build system.  It allows to build
ADOL-C with default options.

Non-default configurations will come in separate commits.

Author: osander1

ADOL-C/CMakeLists.txt

@@ -0,0 +1,2 @@
+add_subdirectory(include)
+add_subdirectory(src)

ADOL-C/include/CMakeLists.txt

@@ -0,0 +1 @@
+add_subdirectory(adolc)

ADOL-C/include/adolc/CMakeLists.txt

@@ -0,0 +1,31 @@
+install(FILES
+        adalloc.h
+        adolc_fatalerror.h
+        adolc.h
+        adolc_openmp.h
+        adolc_sparse.h
+        adoublecuda.h
+        adouble.h
+        adtl.h
+        adtl_hov.h
+        adtl_indo.h
+        adutilsc.h
+        adutils.h
+        advector.h
+        checkpointing.h
+        convolut.h
+        edfclasses.h
+        externfcts2.h
+        externfcts.h
+        fixpoint.h
+        fortutils.h
+        interfaces.h
+        param.h
+        revolve.h
+        taping.h
+        DESTINATION "include/adolc")
+
+add_subdirectory(drivers)
+add_subdirectory(internal)
+add_subdirectory(lie)
+add_subdirectory(tapedoc)

ADOL-C/include/adolc/drivers/CMakeLists.txt

@@ -0,0 +1,6 @@
+install(FILES
+        drivers.h
+        odedrivers.h
+        psdrivers.h
+        taylor.h
+        DESTINATION "include/adolc/drivers")

ADOL-C/include/adolc/internal/CMakeLists.txt

@@ -0,0 +1,15 @@
+install(FILES
+        adubfunc.h
+        common.h
+        paramfunc.h
+        usrparms.h
+        DESTINATION "include/adolc/internal")
+
+# Write options into the file adolc_settings.h
+configure_file(adolc_settings.h.in ${CMAKE_CURRENT_BINARY_DIR}/adolc_settings.h @ONLY)
+install(FILES
+  ${CMAKE_CURRENT_BINARY_DIR}/adolc_settings.h
+  DESTINATION "include/adolc/internal")
+target_include_directories(adolc
+  PRIVATE
+    $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/ADOL-C/include>)

ADOL-C/include/adolc/lie/CMakeLists.txt

@@ -0,0 +1,3 @@
+install(FILES
+        drivers.h
+        DESTINATION "include/adolc/lie")

ADOL-C/include/adolc/tapedoc/CMakeLists.txt

@@ -0,0 +1,3 @@
+install(FILES
+        tapedoc.h
+        DESTINATION "include/adolc/tapedoc")

ADOL-C/src/CMakeLists.txt

@@ -0,0 +1,58 @@
+target_sources(adolc PRIVATE
+               adalloc.c
+               adouble.cpp
+               adouble_tl.cpp
+               adouble_tl_hov.cpp
+               adouble_tl_indo.cpp
+               advector.cpp
+               ampisupport.cpp
+               ampisupportAdolc.cpp
+               checkpointing.cpp
+               convolut.c
+               externfcts.cpp
+               externfcts2.cpp
+               fixpoint.cpp
+               fortutils.c
+               forward_partx.c
+               fos_forward.c
+               fos_pl_forward.c
+               fos_pl_reverse.c
+               fos_pl_sig_forward.c
+               fos_reverse.c
+               fov_forward.c
+               fov_offset_forward.c
+               fov_pl_sig_forward.c
+               fos_pl_sig_reverse.c
+               fov_pl_forward.c
+               fov_reverse.c
+               hos_forward.c
+               hos_ov_reverse.c
+               hos_reverse.c
+               hov_forward.c
+               hov_reverse.c
+               hov_wk_forward.c
+               indopro_forward_pl.c
+               indopro_forward_s.c
+               indopro_forward_t.c
+               int_forward_s.c
+               int_forward_t.c
+               int_reverse_s.c
+               int_reverse_t.c
+               interfaces.cpp
+               interfacesf.c
+               medipacksupport.cpp
+               nonl_ind_forward_s.c
+               nonl_ind_forward_t.c
+               nonl_ind_old_forward_s.c
+               nonl_ind_old_forward_t.c
+               param.cpp
+               revolve.c
+               rpl_malloc.c
+               storemanager.cpp
+               tape_handling.cpp
+               taping.c
+               zos_forward.c
+               zos_pl_forward.c
+              )
+
+add_subdirectory(drivers)

ADOL-C/src/drivers/CMakeLists.txt

@@ -0,0 +1,9 @@
+target_sources(adolc PRIVATE
+               drivers.c
+               driversf.c
+               odedrivers.c
+               odedriversf.c
+               psdrivers.c
+               psdriversf.c
+               taylor.c
+              )

CMakeLists.txt

@@ -0,0 +1,63 @@
+cmake_minimum_required(VERSION 3.19)
+
+project(adol-c
+  VERSION 2.7.3
+  LANGUAGES C CXX
+  DESCRIPTION "A Package for Automatic Differentiation of Algorithms Written in C/C++"
+  HOMEPAGE_URL "https://github.com/coin-or/ADOL-C")
+
+add_library(adolc SHARED)
+add_library(adolc::adolc ALIAS adolc)
+
+target_compile_features(adolc PUBLIC cxx_std_17)
+
+# Make the version of ADOL-C available as compile definitions
+target_compile_definitions(adolc PRIVATE
+  ADOLC_VERSION=${adol-c_VERSION_MAJOR}
+  ADOLC_SUBVERSION=${adol-c_VERSION_MINOR}
+  ADOLC_PATCHLEVEL=${adol-c_VERSION_PATCH})
+
+# Set the public include directory containing headers that will be installed
+target_include_directories(adolc
+  PUBLIC
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/ADOL-C/include>
+    $<INSTALL_INTERFACE:include>)
+
+# Set an include directory for the internally used library headers.
+#
+# This includes the files uni5_for.c, fo_rev.c, and ho_rev.c. Even though
+# they end with .c, they are used like header files.  Together with some
+# preprocessor trickery this is an old-fashioned way to do generic programming.
+target_include_directories(adolc
+  PRIVATE
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/ADOL-C/src>)
+
+
+# handle the options
+# ------------------
+
+set(UINT_TYPE uint32_t)
+set(REAL_TYPE double)
+
+set(ADVBRANCH "#undef ADOLC_ADVANCED_BRANCHING")
+set(ADTL_REFCNT "#undef USE_ADTL_REFCOUNTING")
+set(SPARSE_DRIVERS "#undef SPARSE_DRIVERS")
+set(USE_BOOST_POOL "#undef USE_BOOST_POOL")
+
+# include subdirectories for handling of includes and source files
+# ----------------------------------------------------------------
+
+add_subdirectory(ADOL-C)
+
+
+# export the targets
+# ------------------
+
+include(CMakePackageConfigHelpers)
+include(GNUInstallDirs)
+
+install(TARGETS adolc EXPORT adolcTargets)
+install(EXPORT adolcTargets
+  FILE adolc-targets.cmake
+  NAMESPACE adolc::
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/adolc)