Can I disable link concealing?

[Oneechan69]

Since its not possible to disable the poor line-wrapping.

[MeanderingProgrammer]

Yes, kind of.

The link concealing, along with all the other concealing behavior, is controlled by modifying the conceallevel for the window when rendering. The default we use for this is 3. You can change this to 0, meaning disable concealing, by setting this configuration:

require('render-markdown').setup({
    win_options = { conceallevel = { rendered = 0 } },
})j

Now like I said this changes all concealing behavior and concealing is used in several places, like checkboxes, wikilinks, code blocks to some extent, and potentially some others. All of these will now appear different.

There is no way to change how concealing works at a per line level in neovim, it only works at a window level.

Now there is an alternative and it's something that works outside of this plugin, though a little more complicated. The link concealing is not done by this plugin exactly. It comes from the default highlight from nvim-treesitter: https://github.com/nvim-treesitter/nvim-treesitter/blob/master/queries/markdown_inline/highlights.scm, which specifies all the parts of a link to conceal.

You can override these highlights by creating a file in your config which will be used instead. The contents would largely be a copy minus all the link concealing stuff. If you do this do not modify the plugin configuration at all. Instead create a file at: queries/markdown_inline/highlights.scm with the following contents as an example:

; From https://github.com/nvim-treesitter/nvim-treesitter/blob/master/queries/markdown_inline/highlights.scm minus link concealing
(code_span) @markup.raw @nospell

(emphasis) @markup.italic

(strong_emphasis) @markup.strong

(strikethrough) @markup.strikethrough

(shortcut_link
  (link_text) @nospell)

[
  (backslash_escape)
  (hard_line_break)
] @string.escape

; Conceal codeblock and text style markers
([
  (code_span_delimiter)
  (emphasis_delimiter)
] @conceal
  (#set! conceal ""))

[
  (link_label)
  (link_text)
  (link_title)
  (image_description)
] @markup.link.label

((inline_link
  (link_destination) @_url) @_label
  (#set! @_label url @_url))

((image
  (link_destination) @_url) @_label
  (#set! @_label url @_url))

[
  (link_destination)
  (uri_autolink)
  (email_autolink)
] @markup.link.url @nospell

((uri_autolink) @_url
  (#offset! @_url 0 1 0 -1)
  (#set! @_url url @_url))

(entity_reference) @nospell

; Replace common HTML entities.
((entity_reference) @character.special
  (#eq? @character.special " ")
  (#set! conceal " "))

((entity_reference) @character.special
  (#eq? @character.special "<")
  (#set! conceal "<"))

((entity_reference) @character.special
  (#eq? @character.special "&gt;")
  (#set! conceal ">"))

((entity_reference) @character.special
  (#eq? @character.special "&amp;")
  (#set! conceal "&"))

((entity_reference) @character.special
  (#eq? @character.special "&quot;")
  (#set! conceal "\""))

((entity_reference) @character.special
  (#any-of? @character.special "&ensp;" "&emsp;")
  (#set! conceal " "))

[Oneechan69]

Thanks, this worked.