Can't get recent versions of cprnc to build on my Mac due to problems finding netcdf

[billsacks]

On my Mac, where I have software installed via homebrew, I am having problems building cprnc with the CMake-based build.

cmake runs fine, but when I run make, I get:

/Users/sacks/cprnc/cprnc0/filestruct.F90:2:7:

    2 |   use netcdf
      |       1
Fatal Error: Cannot open module file 'netcdf.mod' for reading at (1): No such file or directory

Adding some debugging messages in the CMakeLists.txt, I see that I'm getting into this block (where NetCDF_FOUND is true but TARGET NetCDF::NetCDF_Fortran is false):

cprnc/CMakeLists.txt

Lines 84 to 88 in cfd4a76

	# We used an old-school find netcdf module. Make the target here
	add_library(netcdf_cprnc INTERFACE)
	target_link_libraries(netcdf_cprnc INTERFACE ${NetCDF_Fortran_LIBRARIES};${NetCDF_C_LIBRARIES})
	target_include_directories(netcdf_cprnc INTERFACE ${NetCDF_Fortran_INCLUDE_DIRS};${NetCDF_C_INCLUDE_DIRS})
	set(CPRNC_NETCDF_FORTRAN_LIB netcdf_cprnc)

but the various variables there (e.g., NetCDF_Fortran_INCLUDE_DIRS) seem to be undefined.

In my CMakeCache.txt I see:

NetCDF_DIR:PATH=/opt/homebrew/lib/cmake/netCDF

and after the find_package, when I print the value of NetCDF_CONFIG, I see that it is /opt/homebrew/lib/cmake/netCDF/netCDFConfig.cmake.

The contents of that file are:

Contents of /opt/homebrew/lib/cmake/netCDF/netCDFConfig.cmake

# NetCDF Configuration Summary
#
# General
#

####### Expanded from @PACKAGE_INIT@ by configure_package_config_file() #######
####### Any changes to this file will be overwritten by the next CMake run ####
####### The input file was netCDFConfig.cmake.in                            ########

get_filename_component(PACKAGE_PREFIX_DIR "${CMAKE_CURRENT_LIST_DIR}/../../../" ABSOLUTE)

macro(set_and_check _var _file)
  set(${_var} "${_file}")
  if(NOT EXISTS "${_file}")
    message(FATAL_ERROR "File or directory ${_file} referenced by variable ${_var} does not exist !")
  endif()
endmacro()

macro(check_required_components _NAME)
  foreach(comp ${${_NAME}_FIND_COMPONENTS})
    if(NOT ${_NAME}_${comp}_FOUND)
      if(${_NAME}_FIND_REQUIRED_${comp})
        set(${_NAME}_FOUND FALSE)
      endif()
    endif()
  endforeach()
endmacro()

####################################################################################

set(NetCDFVersion "4.9.3")
set_and_check(netCDF_INSTALL_PREFIX "/opt/homebrew/Cellar/netcdf/4.9.3")
set_and_check(netCDF_INCLUDE_DIR "/opt/homebrew/Cellar/netcdf/4.9.3/include")
set_and_check(netCDF_LIB_DIR "/opt/homebrew/Cellar/netcdf/4.9.3/lib")
set(netCDF_LIBRARIES netCDF::netcdf)

# include target information
include("${CMAKE_CURRENT_LIST_DIR}/netCDFTargets.cmake")



# Compiling Options
#
set(netCDF_C_COMPILER "clang")
set(netCDF_C_COMPILER_FLAGS " -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64 -O3 -DNDEBUG")
set(netCDF_C_CPP_FLAGS " ")
set(netCDF_LDFLAGS " ")
set(netCDF_AM_CFLAGS "")
set(netCDF_AM_CPPFLAGS "")
set(netCDF_AM_LDFLAGS "")
set(netCDF_SHARED yes)
set(netCDF_STATIC no)

# Features:
#
set(netCDF_HAS_NC2 yes)
set(netCDF_HAS_NC4 yes)
set(netCDF_HAS_HDF4 no)
set(netCDF_HAS_HDF5 yes)
set(netCDF_HAS_PNETCDF no)
set(netCDF_HAS_PARALLEL no)
set(netCDF_HAS_DAP yes)
set(netCDF_HAS_DAP2 yes)
set(netCDF_HAS_DAP4 yes)
set(netCDF_HAS_DISKLESS yes)
set(netCDF_HAS_MMAP yes)
if (netCDF_HAS_HDF4 OR netCDF_HAS_HDF5)
  include(CMakeFindDependencyMacro)
  find_dependency(HDF5)
endif ()

if (no)
  include(CMakeFindDependencyMacro)
  find_dependency(MPI  EXACT)
endif()

The last commit that works for me is f4979ab. This is before the changes in #23 (as well as the following changes in #25 ).

I don't understand CMake well enough to know where to go from here to try to fix this, but I'm happy to work with someone who understands this better. @jgfouca @bartgol @jedwards4b ?

[bartgol]

I carry around this helpful cmake macro:

function(dump_cmake_variables)
  set (opts)
  set (args1v REGEX)
  set (argsMv)
  cmake_parse_arguments (dcv "${opts}" "${args1v}" "${argsMv}" ${ARGN})

  get_cmake_property(dcv_var_names VARIABLES)

  foreach (var_name IN LISTS dcv_var_names)
    if (dcv_REGEX)
      string(REGEX MATCH ${dcv_REGEX} MATCHES ${var_name})
      if (MATCHES)
        message(STATUS "${var_name}=${${var_name}}")
      endif()
    else ()
      message(STATUS "${var_name}=${${var_name}}")
    endif ()
  endforeach()
endfunction()

You can add it somewhere, and then invoke it with dump_cmake_variables(REGEX "^NetCDF") right after the find_package call, and see what NetCDF variables are currently available at that point (perhaps call it again with regex "^netCDF" and again with "^netcdf", just to catch case mismatches). It is possible that the FindNetCDF.cmake module used is somewhat old or perhaps simply not quite what we expected to see.

You can also do

set (CMAKE_FIND_DEBUG_MODE ON)
find_package(NetCDF QUIET COMPONENTS C Fortran)
set (CMAKE_FIND_DEBUG_MODE OFF)

to get a (MUCH MORE) verbose output from find_package, and see exactly what it searched.

Knowing what find_package searched, as well as what netcdf variables were available after find_package, may help coming up with a solution.

[billsacks]

Thanks a lot, @bartgol ! I'm getting the following variables:

-- NetCDFVersion=4.9.3
-- NetCDF_CONFIG=/opt/homebrew/lib/cmake/netCDF/netCDFConfig.cmake
-- NetCDF_CONSIDERED_CONFIGS=/opt/homebrew/lib/cmake/netCDF/NetCDFConfig.cmake
-- NetCDF_CONSIDERED_VERSIONS=4.9.3
-- NetCDF_DIR=/opt/homebrew/lib/cmake/netCDF
-- NetCDF_FOUND=1
-- NetCDF_VERSION=4.9.3
-- NetCDF_VERSION_COUNT=3
-- NetCDF_VERSION_MAJOR=4
-- NetCDF_VERSION_MINOR=9
-- NetCDF_VERSION_PATCH=3
-- NetCDF_VERSION_TWEAK=0

and

-- netCDF_AM_CFLAGS=
-- netCDF_AM_CPPFLAGS=
-- netCDF_AM_LDFLAGS=
-- netCDF_C_COMPILER=clang
-- netCDF_C_COMPILER_FLAGS= -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64 -O3 -DNDEBUG
-- netCDF_C_CPP_FLAGS=
-- netCDF_HAS_DAP=yes
-- netCDF_HAS_DAP2=yes
-- netCDF_HAS_DAP4=yes
-- netCDF_HAS_DISKLESS=yes
-- netCDF_HAS_HDF4=no
-- netCDF_HAS_HDF5=yes
-- netCDF_HAS_MMAP=yes
-- netCDF_HAS_NC2=yes
-- netCDF_HAS_NC4=yes
-- netCDF_HAS_PARALLEL=no
-- netCDF_HAS_PNETCDF=no
-- netCDF_INCLUDE_DIR=/opt/homebrew/Cellar/netcdf/4.9.3/include
-- netCDF_INSTALL_PREFIX=/opt/homebrew/Cellar/netcdf/4.9.3
-- netCDF_LDFLAGS=
-- netCDF_LIBRARIES=netCDF::netcdf
-- netCDF_LIB_DIR=/opt/homebrew/Cellar/netcdf/4.9.3/lib
-- netCDF_SHARED=yes
-- netCDF_STATIC=no

I'm not very familiar with CMake's find_package stuff, but my sense from all this is that it's not using a NetCDF findpackage at all but instead just using /opt/homebrew/lib/cmake/netCDF/NetCDFConfig.cmake (the contents of which I posted in an earlier comment). Does that seem right or am I misunderstanding this?

[bartgol]

Yeah, that seems at least plausible. Perhaps we should replace

if (NetCDF_FOUND)

with

if (NetCDF_C_FOUND AND NetCDF_Fortran_FOUND)

In your case, I think you are finding the C installation of NetCDF, which calls itself "NetCDF", and therefore the first if statement triggers.

[bartgol]

Overall, I think we may have made some modifications that were fine when using a tailored FindNetCDF.cmake module (like the one used by SCORPIO in E3SM), but do rely on some implicit assumptions (e.g., the presence of NetCDF_C_LIBRARIES and the likes). I think modifying the first if statement as I wrote may be a solution that works for everyone. If it fails, we still get some CMake-y way to find the package, before resorting to pkgconfig, so it may be a good solution.

[billsacks]

@bartgol thank you very much. Yes, your suggestion solves the problem for me. i.e., I'm able to build cprnc successfully on my Mac with this change:

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 7b2f112..1a9da76 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -76,7 +76,7 @@ endforeach ()
 
 # Try to find NetCDF dependency. Try standard find_package first.
 find_package(NetCDF QUIET COMPONENTS C Fortran)
-if (NetCDF_FOUND)
+if (NetCDF_C_FOUND AND NetCDF_Fortran_FOUND)
   if(TARGET NetCDF::NetCDF_Fortran)
     set(CPRNC_NETCDF_FORTRAN_LIB NetCDF::NetCDF_Fortran)
     set(CPRNC_NETCDF_C_LIB       NetCDF::NetCDF_C)

Do you feel good enough about that change that you feel it could make sense to open a PR with this? If so, I can do that, or I'm happy to defer to you if you'd like to open it yourself.

[bartgol]

Yeah, I think it makes sense. The call to find_package specifically lists the two components, so we must find them individually. This mod should work with any configuration (with or without the find module, and with or without the netcdfConfig.cmake file). I think it makes sense to open a ninja fix PR.