Common Variables with parameters

[jachin84]

On a regular basis I find myself wanting to do something like this:

//vars.bicep
@export()
var config = {
  identities:[
    {
      name: '${envCode}-identity-frontend'
      roleAssignments: [
        {
          resourceName: 'kv-${envCode}-a-good-name'
          resourceType: 'Microsoft.KeyVault/vaults'
          description: 'Grant ${envCode}-identity-frontend Key Vault Secrets User'
          roleDefinitionGuid: '4633458b-17de-408a-b874-0445c86b69e6'
        }
        {
          resourceName: 'st-${envCode}-a-good-name'
          resourceType: 'Microsoft.Storage/storageAccounts'
          description: 'Grant ${envCode}-identity-frontend Storage Blob Data Operator'
          roleDefinitionGuid: 'b4ebbfbe-c18c-5c95-8387-1334df48050c'
        }
      ]
    }
  ] 
}

//main.bicep
param envCode string = 'D'

import {config} from './vars.bicep'

//Deploy resources, etc.
output identityConfig array = config.identities

Is there any way to parameterize variables like this or something similar.

I am trying to avoid this scenario where I have huge parameter files that only differ by a single letter each line.

[anthony-c-martin]

It sounds like user-defined functions may be a good fit for what you're trying to accomplish:

//shared.bicep
type IdentityRoleAssignment = {
  resourceName: string
  resourceType: string
  description: string
  roleDefinitionGuid: string
}

type Identity = {
  name: string
  roleAssignments: IdentityRoleAssignment[]
}

type Config = {
  identities: Identity[]
}

@export()
func getConfig(envCode string) Config => {
  identities:[
    {
      name: '${envCode}-identity-frontend'
      roleAssignments: [
        {
          resourceName: 'kv-${envCode}-a-good-name'
          resourceType: 'Microsoft.KeyVault/vaults'
          description: 'Grant ${envCode}-identity-frontend Key Vault Secrets User'
          roleDefinitionGuid: '4633458b-17de-408a-b874-0445c86b69e6'
        }
        {
          resourceName: 'st-${envCode}-a-good-name'
          resourceType: 'Microsoft.Storage/storageAccounts'
          description: 'Grant ${envCode}-identity-frontend Storage Blob Data Operator'
          roleDefinitionGuid: 'b4ebbfbe-c18c-5c95-8387-1334df48050c'
        }
      ]
    }
  ] 
}

//main.bicep
param envCode string = 'D'

import { getConfig } from './vars.bicep'

var config = getConfig(envCode)

//Deploy resources, etc.
output identityConfig array = config.identities

[jachin84]

Nice idea but in reality I have many parameters that would be required. Maybe in the order of 10-15 params. I suppose the workaround for this is define a type for the input param for the function and then construct a variable in the main template that get's passed in.

I'll try it out.