transcript-library/justfile at main · AojdevStudio/transcript-library · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
# Transcript Library - Command Launchpad
set dotenv-load := true

# Claude Code with skip permissions
cc := "claude --dangerously-skip-permissions"

# List all recipes
default:
  @just --list

# --- Development ---

# Install dependencies
install:
  bun install

# Start Next.js dev server
dev host="127.0.0.1" port="3000":
  bun run dev -- --hostname {{host}} --port {{port}}

# Build for production using webpack (avoids the Next 16 Turbopack panic)
build:
  bunx next build --webpack

# Start the local app server
start host="127.0.0.1" port="3000":
  just dev {{host}} {{port}}

# Start production server (builds first and allows host/port override)
prod-start host="127.0.0.1" port="3000":
  just build
  HOSTNAME={{host}} PORT={{port}} bun run start

# Run ESLint
lint:
  bun run lint

# Run type checking
typecheck:
  bunx tsc --noEmit

# Format code with Prettier
fmt:
  bunx prettier --write "src/**/*.{ts,tsx,json,css}"

# Run the unattended daily sweep (refresh-only ingest + safe repair, no analysis launch)
daily-sweep:
  node --import tsx scripts/daily-operational-sweep.ts

# Run the legacy nightly analysis workflow explicitly; not the unattended default
insights:
  node --import tsx scripts/nightly-insights.ts

# Rebuild the SQLite-backed catalog snapshot with the supported runtime
rebuild-catalog:
  npx tsx scripts/rebuild-catalog.ts

# Validate catalog parity without replacing the live snapshot
rebuild-catalog-check:
  npx tsx scripts/rebuild-catalog.ts --check

# Backfill canonical/title artifacts for existing insights
backfill-insights:
  bun run scripts/backfill-insight-artifacts.ts

# --- Claude Code Boot ---

# Start Claude with project context loaded
cld:
  {{cc}} --model opus "/prime"

# Quick start (no context preload)
cldq:
  {{cc}} --model opus

# Deterministic setup only (runs hooks, no agent)
cldi:
  {{cc}} --model opus --init

# Setup + agentic install reporting
cldii:
  {{cc}} --model opus --init "/install"

# Setup + interactive onboarding (human-in-the-loop)
cldit:
  {{cc}} --model opus --init "/install true"

# Deterministic maintenance only
cldm:
  {{cc}} --model opus --maintenance

# Maintenance + agentic reporting
cldmm:
  {{cc}} --model opus --maintenance "/maintenance"

# --- Context Loading ---

# Load knowledge base as system context
load-knowledge topic:
  {{cc}} --append-system-prompt "$(cat knowledge/{{topic}}/*.md 2>/dev/null || echo 'No files found for topic: {{topic}}')"

# --- Utilities ---

# Git status (short)
gs:
  git status -sb

# Push current branch
push:
  git push origin HEAD

# Clean build artifacts
clean:
  rm -rf .next node_modules/.cache

# Full reset (reinstall everything)
reset:
  rm -rf node_modules .next package-lock.json
  bun install