How to add build dependencies?

[nemonical]

Hello, I am very new to Nix, and I'm trying to figure out how to set up a Nix development environment for a project I'm working on.
I need to compile the jack crate and that needs to use pkg-config and jack2.dev. I tried adding the dependencies to crates.nixlike

{...}: {
  perSystem = {pkgs, ...}: {
    # declare projects
    # TODO: change this to your workspace's path
    nci.projects."utracker" = {
      path = ./.;
      # export all crates (packages and devshell) in flake outputs
      # alternatively you can access the outputs and export them yourself
      export = true;
    };
    # configure crates
    nci.crates = {
      "jack-sys" = {
        drvConfig.mkDerivation = {
          buildInputs = [ pkgs.jack2.dev ];
          nativeBuildInputs = [ pkgs.pkg-config ];
        };     
      };
    };
  };
}

but the build still fails saying it can't find pkg-config.
Is this the wrong place to put these dependencies?

[90-008]

you want to configure your own crates (not the dependencies). so if your crate was named "utracker" you'd do nci.crates."utracker".drvConfig and so on

[nemonical]

This crates.nix fails though:

{...}: {
  perSystem = {pkgs, ...}: {
    # declare projects
    # TODO: change this to your workspace's path
    nci.projects."utracker" = {
      path = ./.;
      depsDrvConfig.mkDerivation = {
        buildInputs = with pkgs; [ libjack2 ];
        nativeBuildInputs = with pkgs; [ pkg-config ];
      };

      # export all crates (packages and devshell) in flake outputs
      # alternatively you can access the outputs and export them yourself
      export = true;
    };
    # configure crates
    nci.crates = {
      /*"editor" = {
        depsDrvConfig.mkDerivation = {
          buildInputs = with pkgs; [ libjack2 ];
          nativeBuildInputs = with pkgs; [  pkg-config ];
        };
      };*/
    };
  };
}

This crates.nix fails with the same error:

{...}: {
  perSystem = {pkgs, ...}: {
    # declare projects
    # TODO: change this to your workspace's path
    nci.projects."utracker" = {
      path = ./.;
      depsDrvConfig.mkDerivation = {
        buildInputs = with pkgs; [ libjack2 ];
        nativeBuildInputs = with pkgs; [ pkg-config ];
      };

      # export all crates (packages and devshell) in flake outputs
      # alternatively you can access the outputs and export them yourself
      export = true;
    };
    # configure crates
    nci.crates = {
      "editor" = {
        depsDrvConfig.mkDerivation = {
          buildInputs = with pkgs; [ libjack2 ];
          nativeBuildInputs = with pkgs; [  pkg-config ];
        };
      };
    };
  };
}

[90-008]

can you show me the repo where this happens if possible? or an example that reproduces it

[nemonical]

this is my repo
https://github.com/nemonical/utracker

[90-008]

oh sorry yeah that makes perfect sense since cargo is complaining that the environment got changed because the lib only exists in deps drv and not main derivation. you can just do:

    nci.projects."utracker" = let
      commonDeps = {
        buildInputs = with pkgs; [ libjack2 ];
        nativeBuildInputs = with pkgs; [ pkg-config ];
      };
    in {
      path = ./.;
      depsDrvConfig.mkDerivation = commonDeps;
      drvConfig.mkDerivation = commonDeps;
      # export all crates (packages and devshell) in flake outputs
      # alternatively you can access the outputs and export them yourself
      export = true;
    };

or similar. or if editor's the only one needing libjack2 you can move those under there (or whichever crates that need it). i would also recommend using config.nci.crates."foobar" to access another crate's configuration and bring those into a crate that depends on that crate if your configuration gets messy.

[nemonical]

Thanks so much! I'll mark this as the answer now because I think I have no more questions.